注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

老旺旺的个人小站

欢迎你,亲爱的朋友!

 
 
 

日志

 
 
关于我

喜欢编点小程序,大的做不来

网易考拉推荐

易语言工具提示类源码  

2007-06-15 09:51:58|  分类: 技术文档 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

.版本 2

.程序集 工具提示类, , 公开
.程序集变量 hToolTips, 整数型

.子程序 _初始化, , , 当基于本类的对象被创建后,此方法会被自动调用

hToolTips = 0

.子程序 创建, 整数型, 公开, 成功返回工具提示控件句柄,失败返回0
.参数 是否支持多行, 逻辑型, 可空, 默认为假
.参数 是否为气泡提示, 逻辑型, 可空, 默认为假
.局部变量 风格, 整数型

.如果真 (hToolTips ≠ 0)
    返回 (0)
.如果真结束
.如果真 (是否为气泡提示)
    风格 = #TTS_BALLOON
.如果真结束
hToolTips = API_CreateWindowExA (0, “tooltips_class32”, “”, 风格, 0, 0, 0, 0, 0, 0, 0, 0)
API_SetWindowPos (hToolTips, #HWND_TOPMOST, 0, 0, 0, 0, 位或 (#SWP_NOSIZE, #SWP_NOMOVE))
.如果真 (hToolTips ≠ 0 且 是否支持多行)
    API_SendMessage (hToolTips, #TTM_SETMAXTIPWIDTH, 0, 1024)
.如果真结束
返回 (hToolTips)

.子程序 添加工具提示, 整数型, 公开, 成功返回非0,失败返回0
.参数 控件句柄, 整数型
.参数 提示内容, 文本型
.参数 提示工具位置, 逻辑型, 可空, 注明:为真表示总显示在控件的中下方,为假表示跟随鼠标。默认为假
.局部变量 tip, TOOLINFO

.如果真 (hToolTips ≠ 0)
    tip.cbSize = 11 × 4
    tip.uFlags = #TTF_SUBCLASS
    .如果真 (提示工具位置)
        tip.uFlags = 位或 (#TTF_SUBCLASS, #TTF_CENTERTIP)
    .如果真结束
    tip.hwnd = 控件句柄
    tip.uId = 0
    tip.hinst = 0
    tip.lpszText = 提示内容
    API_GetClientRect (控件句柄, tip.rect)
    返回 (API_SendMessageA_TOOLINFO (hToolTips, #TTM_ADDTOOL, 0, tip))
.如果真结束
返回 (0)

.子程序 删除工具提示, , 公开, 没有返回值
.参数 控件句柄, 整数型
.局部变量 info, TOOLINFO

.如果真 (hToolTips ≠ 0)
    info.hwnd = 控件句柄
    API_SendMessageA_TOOLINFO (hToolTips, #TTM_DELTOOL, 0, info)
.如果真结束


.子程序 取提示背景颜色, 整数型, 公开, 返回颜色值,错误返回-1

.如果真 (hToolTips ≠ 0)
    返回 (API_SendMessage (hToolTips, #TTM_GETTIPBKCOLOR, 0, 0))
.如果真结束
返回 (-1)

.子程序 置提示背景颜色, 整数型, 公开, 返回值没有意义
.参数 颜色值, 整数型

.如果真 (hToolTips ≠ 0)
    返回 (API_SendMessage (hToolTips, #TTM_SETTIPBKCOLOR, 颜色值, 0))
.如果真结束
返回 (0)

.子程序 取提示文本颜色, 整数型, 公开

.如果真 (hToolTips ≠ 0)
    返回 (API_SendMessage (hToolTips, #TTM_GETTIPTEXTCOLOR, 0, 0))
.如果真结束
返回 (0)

.子程序 置提示文本颜色, 整数型, 公开, 返回值没有意义
.参数 颜色值, 整数型

.如果真 (hToolTips ≠ 0)
    返回 (API_SendMessage (hToolTips, #TTM_SETTIPTEXTCOLOR, 颜色值, 0))
.如果真结束
返回 (0)

.子程序 更新提示文本, , 公开, 没有返回值
.参数 控件句柄, 整数型
.参数 提示内容, 文本型
.局部变量 info, TOOLINFO

.如果真 (hToolTips ≠ 0)
    info.hwnd = 控件句柄
    info.lpszText = 提示内容
    API_SendMessageA_TOOLINFO (hToolTips, #TTM_UPDATETIPTEXT, 0, info)
.如果真结束


.子程序 置提示延时, 整数型, 公开, 返回值没有意义
.参数 弹出延时, 整数型
.参数 显示延时, 整数型

.如果真 (hToolTips ≠ 0)
    .如果真 (弹出延时 > 0)
        API_SendMessage (hToolTips, #TTM_SETDELAYTIME, #TTDT_INITIAL, 弹出延时)
    .如果真结束
    .如果真 (显示延时 > 0)
        返回 (API_SendMessage (hToolTips, #TTM_SETDELAYTIME, #TTDT_AUTOPOP, 显示延时))
    .如果真结束

.如果真结束
返回 (0)

.子程序 销毁, 整数型, 公开, 销毁工具提示
.局部变量 ret, 整数型

.如果真 (hToolTips ≠ 0)
    ret = API_DestroyWindow (hToolTips)
    .如果真 (ret ≠ 0)
        hToolTips = 0
    .如果真结束

.如果真结束
返回 (ret)

.子程序 取回句柄, 整数型, 公开

返回 (hToolTips)

.子程序 移除工具提示, 整数型, , 没有意义的返回值

.如果真 (hToolTips ≠ 0)
    返回 (API_SendMessage (hToolTips, #TTM_POP, 0, 0))
.如果真结束
返回 (0)

.子程序 置入句柄, 整数型, 公开
.参数 欲置入的句柄, 整数型
.局部变量 ret, 整数型

ret = hToolTips
hToolTips = 欲置入的句柄
返回 (ret)

.子程序 置提示宽度, 整数型, 公开, 返回之前提示的宽度。注:一般在工具提示控件具有“多行”属性时使用。
.参数 宽度, 整数型, , 以像素为单位

.如果真 (hToolTips ≠ 0)
    返回 (API_SendMessage (hToolTips, #TTM_SETMAXTIPWIDTH, 0, 宽度))
.如果真结束
返回 (0)

.子程序 取控件总数, 整数型, 公开, 返回控件数目

.如果真 (hToolTips ≠ 0)
    返回 (API_SendMessage (hToolTips, #TTM_GETTOOLCOUNT, 0, 0))
.如果真结束
返回 (0)

.子程序 取所有控件句柄, , 公开, 没有返回值
.参数 控件句柄数组, 整数型, 参考 数组
.局部变量 info, TOOLINFO
.局部变量 count, 整数型
.局部变量 n, 整数型

.如果真 (hToolTips ≠ 0)
    count = 取控件总数 ()
    .如果真 (count > 0)
        重定义数组 (控件句柄数组, 假, 0)
        info.cbSize = 11 × 4
        .计次循环首 (count, n)
            API_SendMessageA_TOOLINFO (hToolTips, #TTM_ENUMTOOLS, n - 1, info)
            .如果真 (info.hwnd ≠ 0)
                加入成员 (控件句柄数组, info.hwnd)
            .如果真结束

        .计次循环尾 ()
    .如果真结束

.如果真结束


.子程序 取提示文本, 整数型, 公开, 成功返回非0,失败返回0
.参数 控件句柄, 整数型
.参数 缓冲区, 文本型, 参考
.参数 缓冲区大小, 整数型
.局部变量 info, TOOLINFO
.局部变量 ret, 整数型

.如果真 (hToolTips ≠ 0)
    info.cbSize = 11 × 4
    info.hwnd = 控件句柄
    info.lpszText = 取空白文本 (缓冲区大小)
    ret = API_SendMessageA_TOOLINFO (hToolTips, #TTM_GETTOOLINFO, 0, info)
    缓冲区 = info.lpszText
.如果真结束
返回 (ret)

.子程序 _销毁, , , 当基于本类的对象被销毁前,此方法会被自动调用

.如果真 (hToolTips ≠ 0)
    API_DestroyWindow (hToolTips)
.如果真结束

 

  评论这张
 
阅读(953)| 评论(0)
推荐 转载

历史上的今天

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2017